【NIC x Ops（にこぷす）通信】（Terraform編）【初心者向け】TerraformでAWSとGoogle Cloudのマルチクラウド環境を爆速で同時構築してみた！

# ================================================================
# 1. AWS リソース定義
# ================================================================

# ネットワーク (VPC & Subnets)
resource "aws_vpc" "main_vpc" {
  cidr_block           = var.aws_vpc_cidr
  enable_dns_hostnames = true
  enable_dns_support   = true
  tags = {
    Name = "example-vpc"
  }
}

resource "aws_subnet" "public_1" {
  vpc_id            = aws_vpc.main_vpc.id
  cidr_block        = var.aws_public_subnet_1_cidr
  availability_zone = "${var.aws_region}a"
  tags = {
    Name = "example-public-subnet-1"
  }
}

resource "aws_subnet" "public_2" {
  vpc_id            = aws_vpc.main_vpc.id
  cidr_block        = var.aws_public_subnet_2_cidr
  availability_zone = "${var.aws_region}c"
  tags = {
    Name = "example-public-subnet-2"
  }
}

resource "aws_internet_gateway" "gw" {
  vpc_id = aws_vpc.main_vpc.id
  tags = {
    Name = "example-igw"
  }
}

resource "aws_route_table" "public_rt" {
  vpc_id = aws_vpc.main_vpc.id
  route {
    cidr_block = "0.0.0.0/0"
    gateway_id = aws_internet_gateway.gw.id
  }
  tags = {
    Name = "example-public-rt"
  }
}

resource "aws_route_table_association" "a" {
  subnet_id      = aws_subnet.public_1.id
  route_table_id = aws_route_table.public_rt.id
}

resource "aws_route_table_association" "b" {
  subnet_id      = aws_subnet.public_2.id
  route_table_id = aws_route_table.public_rt.id
}

# セキュリティグループ
resource "aws_security_group" "web_sg" {
  name        = "example-web-sg"
  description = "Allow HTTP"
  vpc_id      = aws_vpc.main_vpc.id

  ingress {
    from_port   = 80
    to_port     = 80
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
}

resource "aws_security_group" "db_sg" {
  name   = "example-db-sg"
  vpc_id = aws_vpc.main_vpc.id

  ingress {
    from_port       = 3306
    to_port         = 3306
    protocol        = "tcp"
    security_groups = [aws_security_group.web_sg.id]
  }
}

# Amazon EC2 インスタンス (Web App)
data "aws_ami" "ubuntu" {
  most_recent = true
  filter {
    name   = "name"
    values = ["ubuntu/images/hvm-ssd/ubuntu-jammy-22.04-amd64-server-*"]
  }
  owners = ["099720109477"] # Canonical社の公式アカウントID
}

resource "aws_instance" "web" {
  count                       = var.instance_count
  ami                         = data.aws_ami.ubuntu.id
  instance_type               = "t3.micro"
  subnet_id                   = aws_subnet.public_1.id
  vpc_security_group_ids      = [aws_security_group.web_sg.id]
  associate_public_ip_address = true

  user_data = <<-EOF
              #!/bin/bash
              apt-get update
              apt-get install -y apache2
              echo "Welcome to Example Web App (AWS Server \${count.index + 1})" > /var/www/html/index.html
              systemctl enable apache2
              systemctl start apache2
              EOF

  tags = {
    Name = "example-web-server-\${count.index + 1}"
  }
}

# Amazon RDS (MySQL)
resource "aws_db_subnet_group" "db_subnets" {
  name       = "example-db-subnet-group"
  subnet_ids = [aws_subnet.public_1.id, aws_subnet.public_2.id]
}

resource "aws_db_instance" "mysql" {
  allocated_storage      = 20
  db_name                = "exampledb"
  engine                 = "mysql"
  engine_version         = "8.0"
  instance_class         = "db.m7g.xlarge"
  username               = var.aws_db_username
  password               = var.aws_db_password
  db_subnet_group_name   = aws_db_subnet_group.db_subnets.name
  vpc_security_group_ids = [aws_security_group.db_sg.id] 
  skip_final_snapshot    = true
  publicly_accessible    = false
}

# ================================================================
# 2. Google Cloud (GCP) リソース定義
# ================================================================

# VPCネットワーク
resource "google_compute_network" "gcp_vpc" {
  name                    = "example-gcp-vpc"
  auto_create_subnetworks = false
}

# サブネット
resource "google_compute_subnetwork" "gcp_subnet" {
  name          = "example-gcp-subnet"
  ip_cidr_range = var.gcp_subnet_cidr
  region        = var.gcp_region
  network       = google_compute_network.gcp_vpc.id
}

# ファイアウォール規則 (HTTP 80番ポートを許可)
resource "google_compute_firewall" "allow_http" {
  name    = "example-gcp-allow-http"
  network = google_compute_network.gcp_vpc.name

  allow {
    protocol = "tcp"
    ports    = ["80"]
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["web-server"]
}

# Compute Engine (仮想マシン)
resource "google_compute_instance" "gcp_web" {
  count        = var.instance_count
  name         = "example-gcp-web-\${count.index + 1}"
  machine_type = "e2-micro"
  zone         = var.gcp_zone

  tags = ["web-server"]

  boot_disk {
    initialize_params {
      image = "ubuntu-os-cloud/ubuntu-2204-lts"
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.gcp_subnet.id
    access_config {
      // 外部IPアドレス（パブリックIP）を自動付与
    }
  }

  # 起動スクリプト（Apacheのインストール）
  metadata_startup_script = <<-EOF
    #!/bin/bash
    apt-get update
    apt-get install -y apache2
    echo "Welcome to Example Web App (GCP Server \${count.index + 1})" > /var/www/html/index.html
    systemctl enable apache2
    systemctl start apache2
  EOF
}

# Cloud SQL (MySQL データベース)
resource "google_sql_database_instance" "gcp_mysql" {
  name             = "example-gcp-db"
  database_version = "MYSQL_8_0"
  region           = var.gcp_region
  
  settings {
    tier = "db-custom-16-65536" 
  }
  
  deletion_protection = false # デモ終了後にdestroyしやすくする設定
}